Insertion de caractère dans un nom de mes champs XML

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Insertion de caractère dans un nom de mes champs XML

Ellia

Peace and Love

Bonjour,

J'ai un fichier XML construit comme ceci :

Code :

<toto ID="Bonjour-LaLA-LILO">
<Title>Oui</Title>
</toto>

Et je voudrai faire un template en XSLT, qui à chaque fois que je l'appelle, il me mette un "\" devant chaque tiret. En effet, ces tirets ne passent pas dans ma base données que je crée par la suite!!

Une idée ?

Publicité

gilou

Modérateur
Modzilla

[:google] http://geekswithblogs.net/Erik/arc [...] 20915.aspx
A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Code :

<xsl:template name="string-replace-all">
<xsl:param name="text" />
<xsl:param name="replace" />
<xsl:param name="by" />
<xsl:choose>
<xsl:when test="contains($text, $replace)">
<xsl:value-of select="substring-before($text,$replace)" />
<xsl:value-of select="$by" />
<xsl:call-template name="string-replace-all">
<xsl:with-param name="text"
select="substring-after($text,$replace)" />
<xsl:with-param name="replace" select="$replace" />
<xsl:with-param name="by" select="$by" />
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$text" />
</xsl:otherwise>
</xsl:choose>
</xsl:template>

Voici ceux qu'ils donnent okay. Donc à la place de "by" "replace" et "text", je dois mettre mes vrais caractères à moi ?
Quelle est la différence entre $by et by ?

Merci de votre aide

gilou

Modérateur
Modzilla

Citation :

Voici ceux qu'ils donnent okay. Donc à la place de "by" "replace" et "text", je dois mettre mes vrais caractères à moi ?

non. C'est pas le template qu'il faut modifier, c'est son appel avec un xsl:call-template ou vous passerez les bonnes valeurs aux paramètres.

Citation :

Quelle est la différence entre $by et by ?

Manifestement, il faudrait d'abord apprendre d'abord un peu le XSLT avant de vouloir l'utiliser, parce que poser une question aussi basique montre que vous ne possédez pas les bases.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

rufo

Pas me confondre avec Lycos!

<xsl:param name="text" />
<xsl:param name="replace" />
<xsl:param name="by" />

Ca définit les paramètres du template (ici = fonction) nommé string-replace-all. En gros, c'est pareil que dans un langage de programmation tu définis une fonction avec ses paramètres. Donc là, on nomme les paramètre. Dans la suite du code xsl, $by indique qu'on utilise la variable (donc le contenu) nommée "by".

---------------
Astres, outil de help-desk GPL : http://sourceforge.net/projects/astres, ICARE, gestion de conf : http://sourceforge.net/projects/icare, Outil Planeta Calandreta : https://framalibre.org/content/planeta-calandreta

Ellia

Peace and Love

Etant donné que je ne comprend pas le code que je vous ai filé.
J'ai essayé de remplacer via mon script Php, qui lui, exploite le XML et XSLT.

Cependant, il m'ajoute plusieurs "\" avant mes tirets, mais le soucis c'est que ça fausse mes clauses "where".

si je remplace "a-elle" dans ma creation par "a\-elle",
Et que par la suite je fais : where table='a\-elle'
Cela ne fonctionnera pas, car dans ma base SOURCE, je ne modifie par les avant tirets...

gilou

Modérateur
Modzilla

Et pour faire ce tu voulais juste sur les valeurs d'attribut (pas clair si c'était désiré ailleurs), ceci convient à priori:

Code :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="no"/>
  <!-- definition de la fonction de remplacement -->
  <xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text,$replace)" />
        <xsl:value-of select="$by" />
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text"
          select="substring-after($text,$replace)" />
          <xsl:with-param name="replace" select="$replace" />
          <xsl:with-param name="by" select="$by" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <!-- copie des noeuds en sortie -->                                                    
  <xsl:template match="node()">
    <xsl:copy>
      <!-- appel récursif avec aussi traitement des attributs -->
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
  <!-- appel à la fonction pour modifier les valeurs des attributs -->  
  <xsl:template match="@*">
    <xsl:attribute name="{name(.)}">
      <xsl:call-template name="string-replace-all">
      <xsl:with-param name="text" select="." />
      <xsl:with-param name="replace" select="'-'" />
      <xsl:with-param name="by" select="'\-'" />
      </xsl:call-template>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

Testé avec Saxon sur ce fichier test:

ça donne en sortie:

A+,

Message édité par gilou le 28-06-2012 à 15:21:26

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Je vous remercie pour cette précieuse aide. Mais je n'arrive pas à la fonctionner.

Mon fichier XSLT se présente ainsi :

Code :

<xsl:template match="champ[@genre='liste']">
`<xsl:value-of select="@id"/>` ID
</xsl:template>
<xsl:template match="champ[ @genre='numerique']">
`<xsl:value-of select="@id"/>` ID
</xsl:template>

Et c'est le @id de chaque CHAMP que je veux modifier, comment faire

gilou

Modérateur
Modzilla

Il suffit de transposer bêtement l'appel au template

Code :

<xsl:template match="champ[@genre='liste']">
`<xsl:call-template name="string-replace-all">
<xsl:with-param name="text" select="@id" />
<xsl:with-param name="replace" select="'-'" />
<xsl:with-param name="by" select="'\-'" />
</xsl:call-template>` ID
</xsl:template>
<xsl:template match="champ[@genre='numerique']">
`<xsl:call-template name="string-replace-all">
<xsl:with-param name="text" select="@id" />
<xsl:with-param name="replace" select="'-'" />
<xsl:with-param name="by" select="'\-'" />
</xsl:call-template>` ID
</xsl:template>

A+,

Message édité par gilou le 28-06-2012 à 15:53:59

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Wahouuu !!!! Merci beaucoup Gillou !!!

Mais j'ai essayais ça, pour échapper les quotes :

Code :

<xsl:call-template name="string-replace-all"> <xsl:with-param name="text" select="@id" /> <xsl:with-param name="replace" select=" ' " '" /> <xsl:with-param name="by" select="' \" '" /> </xsl:call-template>"

Cependant, ça ne marche pas, il me laisse les quotes , est ce normal ?

Message édité par Ellia le 12-07-2012 à 16:08:33

Publicité

gilou

Modérateur
Modzilla

Ceci devrait faire l'affaire:

Code :

<xsl:template match="text()[not(normalize-space() = '')]">
<xsl:call-template name="escape-apos">
<xsl:with-param name="string" select="."/>
</xsl:call-template>
</xsl:template>
<xsl:template name="escape-apos">
<xsl:param name="string"/>
<xsl:variable name="apos">'</xsl:variable>
<xsl:choose>
<xsl:when test="not(contains($string, $apos))">
<xsl:value-of select="$string"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="substring-before($string, $apos)"/>
<xsl:text>\'</xsl:text>
<xsl:call-template name="escape-apos">
<xsl:with-param name="string" select="substring-after($string, $apos)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

En principe, c'est 'tail-recursive', donc optimisé par un bon compilo XSLT.
A+,

Message édité par gilou le 12-07-2012 à 21:33:51

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Merci, mais comment faire pour appeler ma fonction au sein de mon code :

est ce comme ceci ?

Code :

<xsl:call-template name="string-replace-all">
<xsl:with-param name="text" select="@id" />
<xsl:with-param name="replace" select="' '" />
<xsl:with-param name="by" select="'\ " />
</xsl:call-template>

gilou

Modérateur
Modzilla

Pour remplacer quoi? trois blancs par \ suivi de deux blancs dans une valeur d'attribut?
il manque un ' en fin de valeur du paramêtre by:

Code :

<xsl:call-template name="string-replace-all">
<xsl:with-param name="text" select="@id" />
<xsl:with-param name="replace" select="' '" />
<xsl:with-param name="by" select="'\ '" />
</xsl:call-template>

Par contre, si c'est pour remplacer un ' par un \' dans le contexte d'une valeur d'attribut id, il faut passer la valeur de l'attribut comme paramètre, par exemple avec un appel (a adapter selon ton contexte d'appel) comme

Code :

<xsl:template match="node()[@id]">  
    <xsl:call-template name="escape-apos">
      <xsl:with-param name="string">
    <xsl:value-of select="@id"/>
      </xsl:with-param>  
    </xsl:call-template>
    <xsl:apply-templates/>
  </xsl:template>

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Excellent. Merci beaucoup

Ellia

Peace and Love

hannn, désolée mais j'ai une autre petite question !!

Alors,

sachant que j'utilise une fonction pour retirer les tirets à mes variables qui s'écrit de cette maniere :

Code :

<xsl:call-template name="string-replace-all">
<xsl:with-param name="text" select="@id" />
<xsl:with-param name="replace" select="'-'" />
<xsl:with-param name="by" select="'\-'" />
</xsl:call-template>

Je voudrai aussi l'utiliser pour traiter les guillemets pour mes variables!
comment faire?

gilou

Modérateur
Modzilla

Ben je vois pas ou est le pb:
on positionne le parametre replace avec le guillemet ouvrant, «, et le parametre by avec le texte de remplacement, \«, par exemple ici,

Code :

<xsl:call-template name="string-replace-all">
  <xsl:with-param name="text" select="@id" />
  <xsl:with-param name="replace" select="'«'" />
  <xsl:with-param name="by" select="'\«'" />
</xsl:call-template>

Et idem pour le guillemet fermant.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Oui merci beaucoup.

Mais je vous dire, comment faire pour appliquer la fonction 2 fois à une même variable.
Sauf que je ne veux pas qu'il me l'écrive 2 fois, mais une seule fois sans les guillemets et sans l'apos !!!

gilou

Modérateur
Modzilla

Une technique standard est de mettre le resultat d'un premier call-template dans une variable et passer la variable comme parametre d'entrée du call template suivant:
Un exemple qui va mettre un \ devant les apostrophes puis les tirets du texte:

Code :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>


  <xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text,$replace)" />
        <xsl:value-of select="$by" />
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text"
          select="substring-after($text,$replace)" />
          <xsl:with-param name="replace" select="$replace" />
          <xsl:with-param name="by" select="$by" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="escape-apos">
  <xsl:param name="string"/>
  <xsl:variable name="apos">&apos;</xsl:variable>
  <xsl:choose>
    <!-- pas d'apostrophe => sortie du texte non modifie -->
    <xsl:when test="not(contains($string, $apos))"><xsl:value-of select="$string"/></xsl:when>
    <xsl:otherwise>
      <!-- apostrophe => sortie du texte avant non modifie -->
      <xsl:value-of select="substring-before($string, $apos)"/>
      <!-- puis de l'apostrophe echappee avec \ -->
      <xsl:text>\&apos;</xsl:text>
      <!-- puis appel recursif pour traiter le texte qui suit l'apostrophe -->
      <xsl:call-template name="escape-apos">
        <xsl:with-param name="string" select="substring-after($string, $apos)"/>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>


  <!-- match des noeud texte non vides -->
  <xsl:template match="text()[not(normalize-space() = '')]">
    <!-- mise du resultat dans une variable -->
    <xsl:variable name="a">
      <xsl:call-template name="escape-apos">
    <xsl:with-param name="string" select="."/>
      </xsl:call-template>
    </xsl:variable>
      <xsl:call-template name="string-replace-all">
        <!-- appel sur le resultat precedent mis en variable -->
        <xsl:with-param name="text" select="$a" />
        <xsl:with-param name="replace" select="'-'" />
        <xsl:with-param name="by" select="'\-'" />
      </xsl:call-template>
  </xsl:template>

</xsl:stylesheet>

Tu peux aussi aller voir cette page, pour la même technique de base (mettre le résultat intermédiaire dans une variable en XSLT 1) mais avec une syntaxe un peu différente.
A+,

Message édité par gilou le 18-07-2012 à 12:55:31

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Ellia

Peace and Love

Okay, merci de votre réponse. Je teste ça et je vous redis !!!!

FORUM HardWare.fr

Programmation

XML/XSL

Insertion de caractère dans un nom de mes champs XML

Sujets relatifs
Lecture, insertion/création fichier	Récupérer les nombres d'une chaine de caractère ???
Insertion checkbox dans page html et affichage valeur	remplacer un caractère dans une chaine
XSLT / XML : position d'un noeud	Macro Excel -> ajouter un caractère dans une cellule
Requete insertion	Problème d'insertion de donnée ODB dans un QTableView
insertion des donne javascripte dans une BD	FPDF et caractère spéciaux
Plus de sujets relatifs à : Insertion de caractère dans un nom de mes champs XML

Page générée en 0.178 secondes