voila dans mon programme vb, je lance un éxecutable Dos, avec la commande shell("c:\soft.exe" ) et je voudrais savoir kan l'éxecution de celui-ci est finie pour pouvoir continuer mes instruction vb
 
merci d'avance

question posée 1001x sur le forum, tu dois pouvoir trouver une réponse aisément via la recherche

kan je fais une recherche sur le mot shell ça me donne rien :'(

 
Tu pourras me dire où? parce que cette question m'intéresse aussi, et même en cherchant rien à faire ! Elle est vraiment posée svt cette question ?  

 
je ne crois pas, la question qui reviens c'est plutot "comment lancer un programme shell dos?".
 
EDIT: un joceBug dans le reply ? ou serais je plutot un ddp

c bon j'ai trouvé la soluce, je la post ce soir dur le forum

c'est bien  

 
ok merci d'avance ça m'intéresse  

' fo mettre toutes ces définitions dans la partie (general du  
' programme )  
 
 Private Type STARTUPINFO
      cb As Long
      lpReserved As String
      lpDesktop As String
      lpTitle As String
      dwX As Long
      dwY As Long
      dwXSize As Long
      dwYSize As Long
      dwXCountChars As Long
      dwYCountChars As Long
      dwFillAttribute As Long
      dwFlags As Long
      wShowWindow As Integer
      cbReserved2 As Integer
      lpReserved2 As Long
      hStdInput As Long
      hStdOutput As Long
      hStdError As Long
   End Type
 
   Private Type PROCESS_INFORMATION
      hProcess As Long
      hThread As Long
      dwProcessID As Long
      dwThreadID As Long
   End Type
 
   Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
      hHandle As Long, ByVal dwMilliseconds As Long) As Long
 
   Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
      lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
      lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
      ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
      ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
      lpStartupInfo As STARTUPINFO, lpProcessInformation As _
      PROCESS_INFORMATION) As Long
 
   Private Declare Function CloseHandle Lib "kernel32" _
      (ByVal hObject As Long) As Long
 
   Private Declare Function GetExitCodeProcess Lib "kernel32" _
      (ByVal hProcess As Long, lpExitCode As Long) As Long
 
   Private Const NORMAL_PRIORITY_CLASS = &H20&
   Private Const INFINITE = -1&
 
   Public Function ExecCmd(cmdline$)
      Dim proc As PROCESS_INFORMATION
      Dim start As STARTUPINFO
 
      ' Initialize the STARTUPINFO structure:
      start.cb = Len(start)
 
      ' Start the shelled application:
      ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
         NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)
 
      ' Wait for the shelled application to finish:
         ret& = WaitForSingleObject(proc.hProcess, INFINITE)
         Call GetExitCodeProcess(proc.hProcess, ret&)
         Call CloseHandle(proc.hThread)
         Call CloseHandle(proc.hProcess)
         ExecCmd = ret&
   End Function
 
 
' ici c'est la partie appel de la fonction =)
 
   Sub Form_Click()
      Dim retval As Long
      retval = ExecCmd("notepad.exe" )
      MsgBox "Process Finished, Exit Code " & retval
   End Sub

je précise que si el programme s'est déroulé correctement retval=0

 
MERCI  

Je viens d'essayer ça marche impec   . Sauf la valeur de  
 
retour qui est tjs égale à 0   . Mais bon c ptet parce que je  
 
suis en VBA et non en VB, je c pas trop. Mais bon ça me suffit  
 
comme ça ! Merci encore