Forum |  HardWare.fr | News | Articles | PC | S'identifier | S'inscrire | Shop Recherche
1473 connectés 

  FORUM HardWare.fr
  Programmation
  Flash/ActionScript

  AS2.0 : Classe menu, votre avis ?

 
 


 Mot :   Pseudo :  
 
Bas de page
Auteur Sujet :

AS2.0 : Classe menu, votre avis ?

n°1328068
blet8533
Posté le 19-03-2006 à 01:18:15  profilanswer
 

SAlut,  
 
Je viens de terminé une premiere ébauche de ma premiere classe AS2.0 et je voulais avoir votre avis sur la syntaxe et sur la structure.
 
Des exemples et le code sont accessibles sur http://manubonnet.free.fr/blog/files/menu/menu.html
 
Voici la classe :  
 

Code :
  1. class menu {
  3. private var conteneur_mc:MovieClip;
  4. private var conteneurParties_mc:MovieClip;
  5. private var conteneurSousParties_mc:MovieClip;
  7. private var cible_mc:MovieClip;
  8. private var parties_mc:MovieClip;
  9. private var sousParties_mc:MovieClip;
  11. private var chargeurImage:MovieClipLoader;
  13. private var orientationMenu:String;
  15. private var chemin:String;
  16. private var menuXML:XML;
  18. private var largeur:Number;
  19. private var hauteur:Number;
  20. private var Coordx:Number;
  21. private var Coordy:Number;
  23. private var profondeur:Number;
  25. private var policePartie:String = "Arial";
  26. private var taillePartie:Number = 13;
  27. private var espacePartie:Number = 10;
  28. private var couleurPartie:Number = 0x000000;
  29. private var couleurFondPartie:Number = 0xFFFFFF;
  30. private var couleurBordurePartie:Number = 0xCCCCCC;
  31. private var courbeBordurePartie:Number = 0;
  32. private var couleurFondOverPartie:Number = 0xFFFFFF;
  33. private var couleurBordureOverPartie:Number = 0xFFFFFF;
  34. private var tailleBordurePartie:Number = 1;
  36. private var policeSousPartie:String = "Arial";
  37. private var tailleSousPartie:Number = 10;
  38. private var espaceSousPartie:Number = 20;
  39. private var couleurSousPartie:Number = 0x000000;
  40. private var couleurFondSousPartie:Number = 0xFFFFFF;
  41. private var couleurBordureSousPartie:Number = 0xEEEEEE;
  42. private var courbeBordureSousPartie:Number = 0;
  43. private var couleurFondOverSousPartie:Number = 0xFFFFFF;
  44. private var couleurBordureOverSousPartie:Number = 0xFFFFFF;
  45. private var tailleBordureSousPartie:Number = 1;
  47. private var tempoQuit:Number = 500;
  48. private var pos:Number = espacePartie/2;
  50. public function menu(cible:MovieClip,
  51.       chemin:String,
  52.       x:Number,
  53.       y:Number,
  54.       l:Number,
  55.       h:Number,
  56.       orient:String,
  57.       tempo:Number,
  58.       profondeur:Number) {
  60.  this.cible_mc = cible;
  61.  this.chemin = chemin;
  62.  this.orientationMenu = orient;
  63.  this.tempoQuit = tempo;
  64.  this.profondeur = profondeur;
  65.  (l == null or l == "undefined" ) ? this.largeur = Stage.width : this.largeur = l;
  66.  (h == null or h == "undefined" ) ? this.hauteur = Stage.height : this.hauteur = h;
  67.  this.Coordx = x;
  68.  this.Coordy = y;
  70. }
  72. public function creerMenu():Void {
  73.  trace("Methode : creerMenu" );
  74.  creerConteneurPrincipal(this.Coordx, this.Coordy);
  75.  chargeXML();
  76. }
  78. //Créer le conteneur principal  
  79. private function creerConteneurPrincipal(x:Number, y:Number):Void {
  80.  trace("Methode : creerConteneurPrincipal" );
  81.  conteneur_mc = cible_mc.createEmptyMovieClip("conteneur_mc", profondeur);
  82.  conteneur_mc._x = x;
  83.  conteneur_mc._y = y;
  85.  creerConteneurParties();
  86. }
  88. //Créer le conteneur des parties  
  89. private function creerConteneurParties():Void {
  90.  trace("Methode : creerConteneurParties" );
  91.  conteneurParties_mc = conteneur_mc.createEmptyMovieClip("conteneurParties_mc", 1);
  92.  creerCadre(conteneurParties_mc, largeur, hauteur, couleurFondPartie, couleurBordurePartie, tailleBordurePartie, courbeBordurePartie);
  93. }
  95. //Créer le conteneur des sous-parties  
  96. private function creerConteneurSousParties(partie:Number, position:Number, nbSousPartie:Number):Void {
  97.  trace("Methode : creerConteneurSousParties" );
  98.  var moi:Object = this;
  99.  conteneurSousParties_mc = conteneur_mc.createEmptyMovieClip("conteneurSousParties_mc", conteneur_mc.getNextHighestDepth());
  100.  fonduApparition(conteneurSousParties_mc,"on" );
  101.  if(orientationMenu == "horizontal" ) {
  102.   conteneurSousParties_mc._x = position;
  103.   conteneurSousParties_mc._y = hauteur;
  104.  } else if(orientationMenu == "vertical" ) {
  105.   conteneurSousParties_mc._x = largeur;
  106.   conteneurSousParties_mc._y = position;
  107.  }
  108.  creerSousParties(partie, nbSousPartie);
  109. }
  111. //Créer un cadre de fond
  112. function creerCadre(cible:MovieClip, l:Number, h:Number, couleurFond:Number, couleurBordure:Number, tailleBordure:Number, courbeBordure:Number):Void {
  113.  trace("Methode : creerCadre" );
  114.  cible.createEmptyMovieClip("cadre_mc", 0);
  115.  cible.cadre_mc.moveTo(0, 0);
  116.  cible.cadre_mc.beginFill(couleurFond);
  117.  cible.cadre_mc.lineStyle(tailleBordure, couleurBordure);
  118.  cible.cadre_mc.lineTo(l-courbeBordure, 0);
  119.  cible.cadre_mc.curveTo(l, 0, l, courbeBordure);
  120.  cible.cadre_mc.lineTo(l, h-courbeBordure);
  121.  cible.cadre_mc.curveTo(l, h, l-courbeBordure, h);
  122.  cible.cadre_mc.lineTo(courbeBordure, h);
  123.  cible.cadre_mc.curveTo(0, h, 0, h-courbeBordure);
  124.  cible.cadre_mc.lineTo(0, 0);
  125.  cible.cadre_mc.endFill();
  126. }
  128. //Charge le fichier XML du menu
  129. private function chargeXML():Void {
  130.  trace("Methode : chargeXML" );
  131.  var moi:Object = this;
  132.  menuXML = new XML();
  133.  menuXML.ignoreWhite = true;
  134.  menuXML.load(chemin);
  135.  menuXML.onLoad = function(success:Boolean)
  136.  {
  137.   if(success)
  138.    moi.creerParties();
  139.  }
  140. }
  142. //Afficher les parties  
  143. private function creerParties():Void {
  144.  trace("Methode : creerParties" );
  145.  parties_mc = conteneurParties_mc.createEmptyMovieClip("parties_mc", 1);
  146.  var nbPartie:Number = menuXML.firstChild.childNodes.length;
  147.  for(var numero:Number = 0; numero<nbPartie; numero++) {
  148.   afficherPartie(numero);
  149.  }
  150. }
  152. //Afficher les sous parties  
  153. private function creerSousParties(partie:Number, nbSousPartie:Number):Void {
  154.  trace("Methode : creerSousParties" );
  155.  sousParties_mc = conteneurSousParties_mc.createEmptyMovieClip("sousParties_mc", 1);
  156.  for(var numero:Number = 0; numero<nbSousPartie; numero++) {
  157.   afficherSousPartie(partie,numero);
  158.  }
  159.   creerCadre(conteneurSousParties_mc, sousParties_mc._width+espaceSousPartie, sousParties_mc._height, couleurFondSousPartie, couleurBordureSousPartie, tailleBordureSousPartie, courbeBordureSousPartie);
  160. }
  162. //Création du bouton
  163. private function afficherPartie(numero:Number):Void {
  164.  trace("Methode : afficherPartie" );
  166.  var moi:Object = this;
  168.  //Infos sur la partie  
  169.  var nomPartie:String = menuXML.firstChild.childNodes[numero].attributes.nom;
  170.  var srcPartie:Function = menuXML.firstChild.childNodes[numero].attributes.src;
  171.  var nbSousPartie:Number =  menuXML.firstChild.childNodes[numero].childNodes.length;
  173.  //Création du bouton
  174.  var bouton_mc:MovieClip = parties_mc.createEmptyMovieClip("bouton_mc"+numero, numero);
  175.  if(orientationMenu == "horizontal" )  {
  176.   bouton_mc._x = pos;
  177.  } else if(orientationMenu == "vertical" )  {
  178.   bouton_mc._y = pos;
  179.   bouton_mc._x = espacePartie/2;
  180.  }
  181.  bouton_mc.onRollOver = function () {
  182.   if(moi.orientationMenu == "horizontal" ) {
  183.    moi.creerCadre(this, this._width+moi.espacePartie, moi.hauteur, moi.couleurFondOverPartie, moi.couleurBordureOverPartie, 0, 0);
  184.    this.cadre_mc._x = -(moi.espacePartie/2);
  185.   } else if(moi.orientationMenu == "vertical" ) {
  186.    moi.creerCadre(this, moi.largeur, this._height, moi.couleurFondOverPartie, moi.couleurBordureOverPartie, 0, 0);
  187.    this.cadre_mc._x = -(moi.espacePartie/2);
  188.   }
  189.   if(nbSousPartie>0) {
  190.    if(moi.orientationMenu == "horizontal" )
  191.     moi.creerConteneurSousParties(numero, this._x-(moi.espacePartie/2), nbSousPartie);
  192.    else if(moi.orientationMenu == "vertical" )
  193.     moi.creerConteneurSousParties(numero, this._y, nbSousPartie);
  194.   } else {
  195.    moi.fonduApparition(moi.conteneurSousParties_mc,"off" );
  196.   }
  197.  }
  198.  bouton_mc.onRollOut = function () {
  199.   this.cadre_mc.removeMovieClip();
  200.   if (!moi.conteneurSousParties_mc(_xmouse, _ymouse, false)) {
  201.    moi.fonduApparition(moi.conteneurSousParties_mc,"off" );
  202.   }
  203.  }
  204.  bouton_mc.onPress = function () {
  205.   moi.chargeSrc(srcPartie);
  206.  }
  208.  //Création de la zone de texte
  209.  var bouton_txt:TextField = bouton_mc.createTextField("bouton_txt", 1, 0, 0, 0, 0);
  210.  bouton_txt.autoSize = true;
  211.  bouton_txt.text = nomPartie;
  212.  bouton_txt.selectable = false;
  214.  //Création des styles du texte
  215.  var mon_format:TextFormat = new TextFormat(policePartie, taillePartie, couleurPartie);
  216.  bouton_txt.setTextFormat(mon_format);
  218.  if(orientationMenu == "horizontal" )
  219.   pos = bouton_txt._width+bouton_mc._x+espacePartie;
  220.  else if(orientationMenu == "vertical" )
  221.   pos = bouton_txt._height+bouton_mc._y+espacePartie;
  223. }
  225. //Création du bouton
  226. private function afficherSousPartie(partie:Number,numero:Number):Void {
  227.  trace("Methode : afficherSousPartie" );
  229.  var moi:Object = this;
  230.  //Variables de la partie  
  231.  var nomSousPartie:String = menuXML.firstChild.childNodes[partie].childNodes[numero].attributes.nom;
  232.  var srcSousPartie:String = menuXML.firstChild.childNodes[partie].childNodes[numero].attributes.src;
  234.  //Création du bouton
  235.  var bouton_mc:MovieClip = sousParties_mc.createEmptyMovieClip("bouton_mc"+numero, numero);
  236.  bouton_mc._y = espaceSousPartie*numero;
  237.  bouton_mc._x = (espaceSousPartie/2);
  238.  bouton_mc.onPress = function () {
  239.   moi.chargeSrc(srcSousPartie);
  240.  }
  241.  bouton_mc.onRollOver = function () {
  242.   moi.creerCadre(this, moi.sousParties_mc._width+moi.espaceSousPartie, this._height, moi.couleurFondOverSousPartie, moi.couleurBordureOverSousPartie, 0, 0);
  243.   this.cadre_mc._x = -this._x;
  244.  }
  245.  bouton_mc.onRollOut = function () {
  246.   this.cadre_mc.removeMovieClip();
  247.  }
  249.  //Création de la zone de texte
  250.  var bouton_txt:TextField = bouton_mc.createTextField("bouton_txt", 1, 0, 0, 0, 0);
  251.  bouton_txt.autoSize = true;
  252.  bouton_txt.text = nomSousPartie;
  253.  bouton_txt.selectable = false;
  255.  //Création des styles du texte
  256.  var mon_format:TextFormat = new TextFormat(policeSousPartie, tailleSousPartie, couleurSousPartie);
  257.  bouton_txt.setTextFormat(mon_format);
  259. }
  261. private function fonduApparition(cible:MovieClip, type:String):Void {
  262.  trace("Methode : fonduApparition : "+type);
  263.  var tempo:Number = getTimer()+tempoQuit;
  264.  var moi:Object = this;
  265.  var fondu:Boolean = false;
  266.  (type == "on" ) ? cible._alpha = 0 : cible._alpha = 100
  267.  cible.onEnterFrame = function () {
  268.   if(type == "on" ) {
  269.    this._alpha += 15;
  270.    if(this._alpha>100)
  271.     delete this.onEnterFrame;
  272.   } else if(type == "off" && (!moi.conteneurSousParties_mc.hitTest(_xmouse, _ymouse, false) or fondu == true) && getTimer()>tempo) {
  273.    fondu = true;
  274.    this._alpha -= 15;
  275.    if(this._alpha<0) {
  276.     delete this.onEnterFrame;
  277.     this.removeMovieClip();
  278.    }
  279.   }
  280.  }
  281. }
  283. private function chargeSrc(src:String):Void {
  284.  trace("Methode : chargeSrc" );
  285.  if(src != "" && src != "undefined" ) {
  286.   var swf_mc:MovieClip;
  287.   swf_mc = conteneur_mc.createEmptyMovieClip("swf_mc", 0);
  288.   swf_mc.loadMovie(src);
  289.  }
  290. }
  292. //------------- STYLES --------------//
  294. //Définir les styles des parties
  295. public function StyleParties(police:String,
  296.         taille:Number,
  297.         espace:Number,
  298.         couleur:Number,
  299.         couleurFond:Number,
  300.         couleurBordure:Number,
  301.         tailleBordure:Number,
  302.         courbeBordure:Number,
  303.         couleurFondOver:Number,
  304.         couleurBordureOver:Number):Void {
  306.  this.policePartie = police;
  307.  this.taillePartie = taille;
  308.  this.espacePartie = espace;
  309.  this.pos = espace/2;
  310.  this.couleurPartie = couleur;
  311.  this.couleurFondPartie = couleurFond;
  312.  this.couleurBordurePartie = couleurBordure;
  313.  this.tailleBordurePartie = tailleBordure;
  314.  this.courbeBordurePartie = courbeBordure;
  315.  this.couleurFondOverPartie = couleurFondOver;
  316.  this.couleurBordureOverPartie = couleurBordureOver;
  317. }
  319. //Définir les styles des sous parties
  320. public function StyleSousParties(police:String,
  321.          taille:Number,
  322.          espace:Number,
  323.          couleur:Number,
  324.          couleurFond:Number,
  325.          couleurBordure:Number,
  326.          tailleBordure:Number,
  327.          courbeBordure:Number,
  328.          couleurFondOver:Number,
  329.          couleurBordureOver:Number):Void {
  331.  this.policeSousPartie = police;
  332.  this.tailleSousPartie = taille;
  333.  this.espaceSousPartie = espace;
  334.  this.couleurSousPartie = couleur;
  335.  this.couleurFondSousPartie = couleurFond;
  336.  this.couleurBordureSousPartie = couleurBordure;
  337.  this.tailleBordureSousPartie = tailleBordure
  338.  this.courbeBordureSousPartie = courbeBordure;
  339.  this.couleurFondOverSousPartie = couleurFondOver;
  340.  this.couleurBordureOverSousPartie = couleurBordureOver;
  341. }
  343. }


 
 
et la déclaration de la classe :
 

Code :
  1. Création du menu
  2. //var monMenuH:menu = new menu('cible', 'chemin du menu', x, y, largeur, hauteur, 'orientation', tempo, profondeur);
  3. var monMenuH:menu = new menu(this, 'menu.xml', 0, 0, null, 18, "horizontal", 100, 0);
  4. //monMenuH.StyleParties('Police', taille, espace, couleur, couleurDeFond, couleurDeBordure, tailledeBordure, courbeCadre, couleurdeFondOver, couleurdeBordureOver);
  5. monMenuH.StyleParties("Verdana", 11, 10, 0x000000, 0xE0E2EB, 0xCCCCCC, 0, 0, 0xBBB7C7, 0xBBB7C7);
  6. //monMenuH.StyleSousParties('Police', taille, espace, couleur, couleurDeFond, couleurDeBordure, tailledeBordure, courbeCadre, couleurdeFondOver, couleurdeBordureOver);
  7. monMenuH.StyleSousParties("Verdana", 11, 18, 0x000000, 0xF8F8F8, 0xCCCCCC, 1, 5, 0xBBB7C7, 0xBBB7C7);
  8. //monMenuH.creerMenu();
  9. monMenuH.creerMenu();


 
avec la structure de l'xml :
 

Code :
  1. <menu>
  2. <partie nom="Utilisation" src="">
  3.  <souspartie nom="Mise en place" src="src/mise_en_place.swf" />
  4.  <souspartie nom="Les paramétres par défaut" src="src/defaut.swf" />
  5.  <souspartie nom="" src="" />
  6.  <souspartie nom="La source" src="src/source.swf" />
  7. </partie>
  8. <partie nom="Exemples" src="">
  9.  <souspartie nom="Menu vertical" src="src/exemple2.swf" />
  11.  <souspartie nom="Menu super méga kitch" src="src/exemple3.swf" />
  12. </partie>
  13. <partie nom="Evolution" src="">
  14.  <souspartie nom="Fonctionnalités en projet" src="src/projet.swf" />
  15.  <souspartie nom="A vous de participer" src="src/participer.swf" />
  16. </partie>
  17. <partie nom="A propos" src="src/a_propos.swf" />
  18. </menu>


 
Merci pour vos avis, c'est tres important pour moi.

mood
Publicité
Posté le 19-03-2006 à 01:18:15  profilanswer
 


Aller à :
Ajouter une réponse
  FORUM HardWare.fr
  Programmation
  Flash/ActionScript

  AS2.0 : Classe menu, votre avis ?

 

Sujets relatifs
Appelle d'une fonction via XML dans une classemodifier class d'un menu dans lequel on est.
différent menuPublicateur de quiz en ligne... vos avis
Votre avis ?[PHP/MYSQL] Affichage de tables dans le menu puis ...
Différence entre srtucture et classeProblème CSS pour un menu
Menu cssmenu contextuel sur dream mx 2004
Plus de sujets relatifs à : AS2.0 : Classe menu, votre avis ?

Forum MesDiscussions.Net, Version 2010.2
(c) 2000-2011 Doctissimo
Page générée en 0.134 secondes

Copyright © 1997-2022 Hardware.fr SARL (Signaler un contenu illicite / Données personnelles) / Groupe LDLC / Shop HFR