[VBA EXCEL 2003]Lister les noms des dossiers d'un repertoire > listbox

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [VBA EXCEL 2003]Lister les noms des dossiers d'un repertoire > listbox

sakuraba

Bonjour et bonne année à tous,

je cherche à lister les noms des dossiers du repertoire c:\temp et les afficher dans un listbox

merci d'avance

j'ai un code qui devrait fonctionner mais je vois pas comment l adapter

Code :

Sub Aff_Feuilles()
a = 0
For Each Ws In ActiveWorkbook.Worksheets
If Ws.Name <> "Total" Then
If Ws.Name <> "!!!Base!!!" Then
ReDim Preserve ListeFeuil(a)
ListeFeuil(a) = Ws.Name
a = a + 1
Else
End If
Else
End If
Next
If a = 0 Then
ReDim Preserve ListeFeuil(0)
ListeFeuil(0) = "aucune feuille"
Else
End If
End Sub

Publicité

Epena

Bonjour,

En utilisant la fonction Dir, cela fonctionne en VBA de Word (extrait de l'aide):

Sub ChercherRépertoire()
Dim Liste() As String
Dim a As Integer
a = 0
MyPath = "c:\temp\"
MyName = Dir(MyPath, vbDirectory)
Do While MyName <> ""
' Ignore le répertoire courant et le répertoire contenant le répertoire courant
If MyName <> "." And MyName <> ".." Then
' Utilise une comparaison au niveau du bit pour vérifier que MyName est un répertoire.
If (GetAttr(MyPath & MyName) And vbDirectory) = vbDirectory Then
ReDim Preserve Liste(a)
Liste(a) = MyName
End If '
End If
MyName = Dir ' Extrait l'entrée suivante
Loop
ListBox.List = Liste
End Sub

Cordialement

Epéna

Epena

La même procédure fonctionne en VBA Excel

sakuraba

ok je te remercie je vais regarder

sakuraba

j'ai un petit souci

Epena

Bonjour,
Il faut déclarer la variable tableau. On peut faire comme ceci avec une procédure :

Code :

Dim Liste() As String
Private Sub CommandButton1_Click()
Call ChercherRépertoire
ListBoxClient.List = Liste
End Sub
Sub ChercherRépertoire()
Dim a As Integer
a = 0
MyPath = "c:\temp\"
MyName = Dir(MyPath, vbDirectory)
Do While MyName <> ""
' Ignore le répertoire courant et le répertoire contenant le répertoire courant
If MyName <> "." And MyName <> ".." Then
' Utilise une comparaison au niveau du bit pour vérifier que MyName est un répertoire.
If (GetAttr(MyPath & MyName) And vbDirectory) = vbDirectory Then
ReDim Preserve Liste(a)
Liste(a) = MyName
a = a + 1
End If '
End If
MyName = Dir ' Extrait l'entrée suivante
Loop
End Sub

Ou bien de cette façon avec une fonction qui renvoit un tableau (Type variant++++++)

Code :

Private Sub CommandButton1_Click()
Dim Liste As Variant
Répertoire = "c:\temp\"
Liste = ChercherRépertoire(Répertoire)
ListBoxClient.List = Liste
End Sub
Function ChercherRépertoire(MyPath) As Variant 'La fonction renvoie un tableau
Dim MaListe() As String
Dim a As Integer
a = 0
MyName = Dir(MyPath, vbDirectory)
Do While MyName <> ""
' Ignore le répertoire courant et le répertoire contenant le répertoire courant
If MyName <> "." And MyName <> ".." Then
' Utilise une comparaison au niveau du bit pour vérifier que MyName est un répertoire.
If (GetAttr(MyPath & MyName) And vbDirectory) = vbDirectory Then
ReDim Preserve MaListe(a)
MaListe(a) = MyName
a = a + 1
End If '
End If
MyName = Dir ' Extrait l'entrée suivante
Loop
ChercherRépertoire = MaListe
End Function

Cela devrait fonctionner
Cordialement

Epéna

sakuraba

j'ai toujours l erreur
"impossible de definir la propriété list ?

Epena

Est-ce que le tableau liste a bien été déclaré dans la zone déclarative pour la procédure?
Dim Liste() As String

ou pour la fonction
Private Sub CommandButton1_Click()
Dim Liste As Variant

Cela fonctionne en word et excel 97

sakuraba

c'est bon ça marche c est parce qu'il y avait pas de repertoire dans le c:\Temp

merci beaucoup

sakuraba

voici mon travail corrigé :

'la fonction de recherche de nom de repertoire et stockage dans un array

Code :

Function ChercherRépertoire(MyPath) As Variant 'La fonction renvoie un tableau
Dim MaListe() As String
Dim a As Integer
a = 0
MyName = Dir(MyPath, vbDirectory)
Do While MyName <> ""
' Ignore le répertoire courant et le répertoire contenant le répertoire courant
If MyName <> "." And MyName <> ".." Then
' Utilise une comparaison au niveau du bit pour vérifier que MyName est un répertoire.
If (GetAttr(MyPath & MyName) And vbDirectory) = vbDirectory Then
ReDim Preserve MaListe(a)
MaListe(a) = MyName
a = a + 1
End If '
End If
MyName = Dir ' Extrait l'entrée suivante
Loop
If a = 0 Then
ReDim Preserve MaListe(0)
MaListe(0) = "-----Aucun Client-----"
Else
End If
ChercherRépertoire = MaListe
End Function

la fonction pour rechercher un repertoire et le creer si besoin

Code :

Function RépertoireExiste(Chemin As String) As Boolean
On Error Resume Next
RépertoireExiste = GetAttr(Chemin) And vbDirectory
If RépertoireExiste = True Then
Exit Function
Else
MkDir (Chemin)
End If
End Function

enfin l'appel des fonctions pour remplir la listbox

Code :

Private Sub Userform_initialize()
Dim Liste As Variant
Dim Répertoire As String
Répertoire = "c:\Facturation\"
Call RépertoireExiste("c:\Facturation\" )
Liste = ChercherRépertoire(Répertoire)
ListBoxClient.List = Liste
End Sub

merci à vous pour le coup de pouce ( pied plutot ) @++

Publicité

nayaphykit

bonjour,

je commence a utiliser vba/excel depuis peu et la j'ai un probleme que je n'arrive pas à resoudre.
g bien lu tout ce qui ce trouve au dessus et je crois faire la meme chose ke ce que vous avez écrit cependant ca ne fonctionne pas :s

voila mon probleme. je veux afficher dans un listbox (ListInfosBox) les données d'une feuille excel cette feuille étant ouverte en parallele. le nombre de colonne et de ligne de cette feuille est variable mais il est recuperé o moment de l'ouverture.
je recupere toutes les données de la feuille dans un tableau et apres je veux mettre le tableau dans la listbox et ca me met le msg d'erreur suivant : "erreur d'execution '380' : impossible de définir la propriété list. valeur de propriete non valide"

voila mon code :

Code :

Sub Liste(iChoix As Integer)
Dim i As Integer, j As Integer, iCountRow As Integer, iCountCol As Integer
Dim wbInfosBaseBook As Workbook
Dim wsFeuille As Worksheet
Dim tabValTemp() As Variant
Set wbInfosBaseBook = Application.Workbooks.Open("U:\Data\Workspace\semaine2\Projet\FichiersUtiles\InfosBase.xls" )
Set wsFeuille = wbInfosBaseBook.Worksheets(iChoix + 1)
iCountRow = wsFeuille.Cells.Find("*", [A1], , , xlByRows, xlPrevious).Row
For i = 1 To iCountRow + 1
For j = 1 To iCountCol
tabValTemp(i, j) = Range("A1" ).Offset(i, j)
Next j
j = 1
Next i
ListInfosBox.List = tabValTemp
End Sub

merci d'avance pour vos réponse

bye

Naya

FORUM HardWare.fr

Programmation

VB/VBA/VBS

[VBA EXCEL 2003]Lister les noms des dossiers d'un repertoire > listbox

Sujets relatifs
excel : fonction pour effacer le contenu d'une cellule	espace dans les noms
probléme MySql et visual.net 2003	partir le code VBA d'un bouton d'un formulaire access
DLL Manquante Access VBA	[VBA] Probleme pour sauvegarder un classeur
System.Text.Encoding en VBA Word : possible ?	[VBA] ptite demande
macro excel et fichier normal.dot	[VBA PPT2003] Fonction FileDialog(msoFileDialogSaveAs) choix du filter
Plus de sujets relatifs à : [VBA EXCEL 2003]Lister les noms des dossiers d'un repertoire > listbox

Page générée en 0.065 secondes