otobox Maison fondée en 2005 | Solution qui fonctionne sous Access 97 et 2003.
Dans un module macro voici le code à coller (ne mettre que ce code dans ce module, que tu peux sauvegarder sous le nom FonctionOuvrirDossier :
Code :
- Option Compare Database
- Option Explicit
- Private Const BIF_RETURNONLYFSDIRS = 1
- Private Const BIF_DONTGOBELOWDOMAIN = 2
- Private Const BIF_NEWDIALOGSTYLE As Long = &H40
- Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
- Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, _
- ByVal lpBuffer As String) As Long
- Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, _
- ByVal lpString2 As String) As Long
- Private Type BrowseInfo
- hWndOwner As Long
- pIDLRoot As Long
- pszDisplayName As Long
- lpszTitle As Long
- ulFlags As Long
- lpfnCallback As Long
- lParam As Long
- iImage As Long
- End Type
- Public Function SelectFolder(Titre As String, Handle As Long) As String
- Dim lpIDList As Long
- Dim strBuffer As String
- Dim strTitre As String
- Dim tBrowseInfo As BrowseInfo
- strTitre = Titre
- With tBrowseInfo
- .hWndOwner = Handle
- .lpszTitle = lstrcat(strTitre, "" )
- .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN + BIF_NEWDIALOGSTYLE
- End With
- lpIDList = SHBrowseForFolder(tBrowseInfo)
- If (lpIDList) Then
- strBuffer = String(260, vbNullChar)
- SHGetPathFromIDList lpIDList, strBuffer
- SelectFolder = Left(strBuffer, InStr(strBuffer, vbNullChar) - 1)
- End If
- End Function
|
Ensuite, dans le formulaire :
- créer une textbox que tu appelles txtURL
- créer un bouton que tu appelles cdeSelectionRepertoire, pour sa caption tu peux mettre Parcourir et ensuite tu associes le code ci-dessous sur l'évènement Sur clic :
Code :
- Private Sub cdeSelectionRepertoire_Click()
- Dim strchemin As String
- strchemin = SelectFolder("Sélectionnez un répertoire :", Me.hwnd)
- If strchemin <> "" Then txtURL = strchemin
- End Sub
|
---------------
OtObOxBlOg - - - Etre seul à avoir tort c'est plus difficile, mais c'est bien plus beau que d'avoir raison avec une bande de cons
|