Macro VB

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Macro VB

atmakefka

salut à tous

je cherche a écrire une macro sous excel qui doit faire la chose suivante : j´ai une feuille excel avec une colonne A et une B, et x nombre de ligne

je veux que ma macro me pemette de trouver en fonction de Ax donné, ce qu´il y a a coté en Bx

autrement dit me donner Bx pour tout Ax donné
je sais pas trop comment m´y prendre..c´est une function? une sub ? :??:

merci d'avance!

Publicité

fusion_sadam

cells(LIGNE, COL) te renverra le contenu de la énieme ligne et énieme colonne

si tu veux la colonne suivante : cells(LIGNE, COL +1)

atmakefka

merci c'est deja ça

fusion_sadam

ben je vois pas trop ce que tu veux faire exactement
mais essaye deja de faire une macro et dis nous où ca plante

atmakefka

ben je vais donner un exemple : si par exemple dans A1 il y a ecrit "nom" et dans B1 "prenom", je veux une macro qui me donne "prenom" quand je tape "nom"

atmakefka

au fait VBA, pas VB

AlainTech

Pas trouvé? Cherche encore!

Solution pur VBA (sans utiliser les fonctionalités d'Excel):

Sub prenom()
Dim rNoms As Range
Dim sNom As String
Dim vI As Variant
Set rNoms = Range([A1], [A1].End(xlDown))
sNom = InputBox("Nom?", "Recherche prénom" )
For Each vI In rNoms
If UCase(vI) = UCase(sNom) Then
MsgBox (vI.Cells(1, 2))
Exit For
End If
Next vI
End Sub

Pas de gestion des erreurs (si le nom n'existe pas, pas de résultat)
Pas de gestion des doublons (Marc Dupont et Pierre Dupont)

Message édité par AlainTech le 11-05-2005 à 23:54:24

---------------
Si on vous donne une info qui marche, DITES-LE!!!! ------ Si vous trouvez seul, AUSSI, votre solution peut servir à d'autres! ------ Je dois la majorité de mes connaissances à mes erreurs!

atmakefka

Merci
j'avais écris ceci :

Dim Compteur As Integer, prenom As String
Dim Cel As Range
Set Cel = Range("A1" )

Compteur = 1

Do While Cel.Offset(Compteur) <> ""
If Cel.Offset(Compteur) = "nom" Then
Exit Do
End If

Compteur = Compteur + 1

Loop

prenom = Cel.Offset(Compteur, 1)
MsgBox "Le prenom de nom est " & prenom

-----------------------
le probleme est que je dois ecrire dans ma macro le nom a la place de "nom", puis l'executer pour qu'elle m'affiche le prenom dans une msgbox..or je veux saisir directement sous excel le nom dans une cellule, et qu'une autre cellule me donne le prénom..comment je fais??

Message édité par atmakefka le 12-05-2005 à 00:07:10

AlainTech

Pas trouvé? Cherche encore!

Dans ce cas, les formules d'Excel font parfaitement l'affaire.
Imaginons que tu tapes le nom en D1 et que tu veuilles le prénom en E1, dans la cellule E1 tu mets cette formule:

=RECHERCHEV(D1;A:B;2;FAUX) (Sur Excel en français)
=VLOOKUP(D1;A:B;2;FALSE) (Excel en anglais)

AlainTech

Pas trouvé? Cherche encore!

Mais, si tu tiens absolument à faire du VBA, tu peux mettre ce code dans ta FEUILLE:

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Select Case Target.Address
Case "$D$1"
[E1] = Prenom([D1])
End Select
End Sub

Function Prenom(sNom As String) As String
Dim rNoms As Range
Dim vI As Variant
Set rNoms = Range([A1], [A1].End(xlDown))
For Each vI In rNoms
If UCase(vI) = UCase(sNom) Then
Prenom = vI.Cells(1, 2)
Exit For
End If
Next vI
If Prenom = "" Then
MsgBox ("Pas trouvé" )
End If
End Function

Mêmes conditions que plus haut et pas de gestion des erreurs.

Edit --> Ajout du msgbox si pas trouvé

Message édité par AlainTech le 12-05-2005 à 08:40:57

Publicité

atmakefka

Merci !

atmakefka

Rebonjour,
j'ai encore des problèmes avec un code qui doit faire quelque chose de plus compliqué. Je dois extraire dans une nouvelle feuille le journal d'un utilisateur particulier donné (toutes les colonnes en fait). problème, certains utilisateurs apparaissent plusieurs fois. du coup avec mes essais de code je selectionnai qu'une seul ligne de ces utilisateurs, et je n'arrive pas de toutes façons a copier dans une nouvelle et unique feuille , ca m'en cree une nouvelle a chaque fois. apres il y a des problemes de saut de ligne, et j'en passe
la feuille excel ce presente comme ceci

En esperant que quelqu'un pourra m'aider.. merci

Code :

Sub extraire_dans_une_nouvelle_feuille_le_journal_d_un_utilisateur_particulier_donné()
Dim nom_utilisateur As Range
Dim login
Dim login_demandé
Set nom_utilisateur = Range([F2], [F2].End(xlDown))
login_demandé = InputBox("Nom d'utilisateur ?" )
For Each login In nom_utilisateur
If login = login_demandé Then
login.EntireRow.Select
Selection.Copy
Sheets.add
=> ???????
ElseIf login <> login_demandé Then
MsgBox ("Ce nom d'utilisateurou ce login) n'existe pas." )
Exit For
End If
Next login
End Sub

AlainTech

Pas trouvé? Cherche encore!

Ce que je t'ai fait ne correspond pas tout à fait à ce que tu demandais.
En réalité, ça en fait plus.
Je prends toutes les lignes de ta feuille et j'en crée une feuille par utilisateur.
Vois si tu peux en extraire qqch d'utile pour toi.
J'ai nommé la feuille d'origine "Data".

Sub Extract()
Dim bSheetExists As Boolean
Dim iNextRow As Long
Dim rActivity As Range
Dim rHeading As Range
Dim vI As Variant
Dim vJ As Variant
Sheets("Data" ).Activate ' Activer la feuille dont les données vont être
' extraites (feuille "source" )
Set rActivity = Range([A2], [A2].End(xlDown)) ' Créer un range de la première
' colonne
Set rHeading = Rows(1) ' Créer un range de l'entête pour pouvoir le copier
For Each vI In rActivity ' Parcourir toutes les cellules de la 1e colonne
bSheetExists = False ' La feuille recherchée n'est pas encore trouvée
For Each vJ In Worksheets ' Parcourir toutes les feuilles
If vJ.Name = vI.Cells(1, 6) Then ' Si le nom de la feuille = le contenu de la
' cellule en 6e colonne de la ligne
bSheetExists = True ' La feuille est trouvée
Exit For ' et sortie de la boucle de recherche
End If
Next vJ ' Feuille suivante (si pas eu de sortie avant)
If bSheetExists Then ' Si la feuille a été trouvée
vJ.Activate ' Activer cette feuille
Else ' Si elle n'a pas été trouvée
Worksheets.Add After:=Worksheets(Worksheets.Count) ' En créer une et la mettre
' derrière les autres
ActiveSheet.Name = vI.Cells(1, 6) ' Lui donner comme nom le contenu de la
' cellule de la 6e colonne de la ligne
' parcourue par la boucle
rHeading.Copy ([A1]) ' Y copier l'entête
End If
iNextRow = [A1].SpecialCells(xlLastCell).Row + 1 ' Déterminer la 1ere ligne
' vide de la feuille trouvée
' ou créee
vI.EntireRow.Copy (Cells(iNextRow, 1)) ' Y copier la ligne de la feuille
' source où la boucle est arrivée
Next vI ' Ligne "source" suivante
End Sub

Edit --> Ajout des commentaires

Message édité par AlainTech le 14-05-2005 à 10:35:14

atmakefka

merci je vais voir

atmakefka

ça marche, mais ca le fait directement. je vais modifier pour que ça soit pour un utilisateur donné. encore merci

Message édité par atmakefka le 13-05-2005 à 12:31:48

atmakefka

oups double post

Message édité par atmakefka le 13-05-2005 à 12:31:03

AlainTech

Pas trouvé? Cherche encore!

C'est bien ce que je t'avais dit: ça en fait plus que tu ne demandais.

atmakefka

Oui mais faut que j'y arrive par moi même, c'est pour ça, et comprendre aussi

atmakefka

Une derniere chose stp, tu pourrais expliquer un peu le prog ? ou commenter ? je ne comprends pas tout

AlainTech

Pas trouvé? Cherche encore!

Voilà, j'ai mis les commentaires.
N'hésite pas à poser des questions sur ce que tu ne comprends pas.

atmakefka

merci!
désolé de t'avoir demandé ça mais c'est parceque je n'arrivais pas a modifier le code pour que ce soit pour un utilisateur donné
je vais voir ça, merci

atmakefka

arf j'y arrive pas je suis nul

atmakefka

je demande encore votre aide

atmakefka

bon j'ai reussi, j'aurai peut etre besoin d'aide plus tard encore
merci

atmakefka

edit

Message édité par atmakefka le 24-05-2005 à 10:14:17

atmakefka

pepette54710

lol. Tu ne serais pas en deug MISASHS en 1ere année?

AlainTech

Pas trouvé? Cherche encore!

J'ai dans l'idée que vous devez vous connaître.
Mêmes posts sur plusieurs forums...

Publicité

FORUM HardWare.fr

Programmation

VB/VBA/VBS

Macro VB

Sujets relatifs
Macro formule cellule #NOM?...	Macro pour trouver et recopier toutes les lignes ayant une valeur com
[RESOLU] Macro - copie de fichier	liaison macro
HELP !! Traduire une Macro de WORD à EXCEL	Modifier programme, macro?
Fusion word depuis une Macro Excel	Lancer macro Word
Lancer une macro après modification d'un tableau croisé?	Excel / Word macro à lancer et Textbox
Plus de sujets relatifs à : Macro VB

Page générée en 0.070 secondes