Gestion de tableau avec tri automatique

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Gestion de tableau avec tri automatique

kabol

Bonjour,

Je vous contacte car débutant en macro VB Excel, je souhaiterai avoir vos conseil pour régler le problème suivant:

-> Dans une worksheet, j'ai un tableau de la forme suivante

titreA titreB titreC titreD titreE
vache ble 10.2.1 ville valide
cheval mais VIDE ferme valide
vache ble 5.2.1 ferme valide
vache mais VIDE ville valide
vache ble 5.4.6 ville valide
cheval seigle 100.0.7 ferme valide
cheval mais 3.6.1 ville valide

Hypotheses:
* L'espace doit etre interprété comme séparateur de cellule
*La taille du tableau peut varier et l'emplacement des colonnes aussi. Ici on va travailler avec les colonnes nommées: "titreA" et "titreC", mais leur emplacement peut varier (seul leur nom est connu et fixe). Pour ça j'avais pensé à l'utilisation d'une fonction de calcul de la taille du tableau et une fonction de recherche de titre de colonne.
* Quand j'écris VIDE: cela signifie que le contenu de la cellule est réellement vide

1/ Je souhaite trouver la colonne "titreC" et utiliser un filtre automatique pour ne garder QUE les lignes NON vide (similaire à l'option "Non Blank" du filtre automatique sous Office 2003). Dans notre cas les lignes 3 et 5 ne doivent plus apparaitre.

2/ Je souhaite trier la colonne "titreC" préalablement filtré de façon croissante. Le probleme qu'on rencontre ici (existant d'ailleurs aussi avec le filtre automatique) c'est que par ex: 10.2.1 sera devant 5.2.1, ce que je voudrai éviter.

3/ Enfin, j'aimerai bien pouvoir filtrer de nouveau le résultat de l'étape précédente suivant la colonne "titreA" en ne gardant que les lignes avec le mot "vache". J'imagine qu'ici aussi la fonction de filtre automatique va être utile

Le resultat obtenu des 3 étapes précédentes devrait avoir la forme suivante:

titreA titreB titreC titreD titreE
vache ble 5.2.6 ferme valide
vache ble 5.22.3 ville valide
vache ble 10.2.1 ville valide

4/Une fois ce tri effectué, je souhaiterai copier ce résultat dans une autre worksheet et supprimer les colonnes "titreB" et "titreD", afin d'obtenir dans une nouvelle worksheet créé:

titreA titreC titreE
vache 5.2.6 valide
vache 5.22.3 valide
vache 10.2.1 valide

5/ Et dernière étape (si pas trop compliqué), je souhaiterai pouvoir insérer une ligne (de la longueur du tableau où toutes les cellules sont fusionnées) et où serait écrit le numéro de section basé UNIQUEMENT sur le premier nombre des cellules de la colonne "titreC" (ex: 5.2.6 -> nombre 5, 10.2.1 -> nombre 10). Cette ligne devra être affiché des que le nombre change.
Donc dans l'exemple cela donnerait:

titreA titreC titreE
*** SECTION 5 *********
vache 5.2.6 valide
vache 5.22.3 valide
*** SECTION 10 *******
vache 10.2.1 valide

Je me suis fais une macro sous Excel en mode enregistrement automatique résolvant mon problème, mais le code est vraiment moche!
Donc voilà je me demandais si quelqu'un pourrait m'aider à construire une macro un peu plus propre.

Merci d'avance pour votre aide,

:bounce:

Publicité

kiki29

Salut, cela te fera un excellent exercice d'optimisation manuelle du code généré par l'enregistreur de macros plutôt que d'attendre du tout cuit

---------------
Myanmar 90/91 : http://gadaud.gerard.free.fr/publi [...] index.html

kabol

Salut kiki29,

Je n'attends pas du tout cuit, mais vois tu la dernière fois où j'ai codé cela remonte à plus de 10 ans durant mes études où j'ai fais plusieurs années de C, de Java,... Et honnêtement j'adorais la prog. Mais voila, dans mon travail je ne suis plus du tout amener à programmer et donc j'ai perdu mes réflexes même si les principes de programmation, c'est comme le vélo on n'oublie pas.

Donc vois-tu l'idée en venant sur ce forum à la rencontre de gars expérimentés et passionnés qui eux ont tous les reflexes, je recherche avant tout une aide pour la structure de mon code avec des fonctions de bases que bien entendu par la suite je vais devoir adapter.
Par ailleurs tu t'imagines bien que mon probleme de base est un peu plus compliqué que trier des "vaches" dans un tableau de 6 lignes.
Donc bien entendu je compte mettre les mains dans le cambouis. Mais je sais qu'à l'époque ou je programmais, pour résoudre un énoncé comme ça il m'aurait fallu moins de 30min .... maintenant malheureusement (étant en plus newbie en VBA), le temps qui m'est nécessaire en partant de zéro est considérablement plus long que si j'arrive à partir avec une base assez bien faite.

En tout cas merci d'avance, pour toute personne ayant l'expérience lui permettant de m'aider sur ce problème sans que cela lui bouffe une journée ;-)

kabol

Pour les passionnés, je vous donne un bout de code qu'un certain Mercatog m'a gentil fournit sur un autre forum:

Code :

'---------------------------------------------------------------------------------------
'Sub qui permet de copier les données de la feuille SOURCE vers la feuille DESTINATION et reformatage des données suivant les explications fournies
'//!\\ Adapter dans cette sub les noms des 2 feuilles SOURCE et DESTINATION
' Adapter aussi les mots TitreC et vache
'---------------------------------------------------------------------------------------
'
Private Sub FormaterDonnees()
Dim c As Range, v As Range
Dim i As Integer
Dim Tb
Application.ScreenUpdating = False
'On efface le contenu éventuel de la feuille Destination
Worksheets("DESTINATION" ).UsedRange.Clear
With Worksheets("SOURCE" )
'On recherche la colonne TitreC
Set c = .UsedRange.Find("TitreC", LookIn:=xlValues, lookat:=xlWhole)
If Not c Is Nothing Then
c.CurrentRegion.Copy Worksheets("DESTINATION" ).Range("A1" )
Set c = Nothing
End If
End With
With Worksheets("DESTINATION" )
'Suppression des colonnes D ensuite B
.Columns(4).Delete
.Columns(2).Delete
Set c = .Range("A1" ).CurrentRegion
'Suppression des lignes ne contenant pas vache en colonne TitreA (colonne 1)
Call SupprFiltre(c, 1, "vache" )
'Suppression des lignes vides de la colonne TitreC (Colonne 2, qui était colonne 3 avant la suppression de la colonne TitreB)
Call SupprFiltre(c, 2, "*" )
'On éclate les nombres séparés par le point dans les colonnes D,E et F
For Each v In Intersect(c, .Range("B:B" ))
Tb = Split(v, "." )
For i = 0 To UBound(Tb)
v.Offset(0, i + 2) = Tb(i)
Next i
Next v
Set c = c.Resize(c.Rows.Count, c.Columns.Count + 3)
'On tri sur D, puis E enfin F
c.Sort Key1:=.Range("D1" ), Order1:=xlAscending, Key2:=.Range("E1" ), Order2:=xlAscending, Key3:=.Range("F1" ), Order3:=xlAscending, Header:=xlYes
'On insère une ligne entre sections
Call SepareSections(c)
'On supprime les colonnes D,E et F
.Range("D:F" ).EntireColumn.Delete
Set c = Nothing
End With
End Sub
'---------------------------------------------------------------------------------------
'Sub qui permet de supprimer les lignes de LaPlage
'dont les cellules de la colonne LaColonne ne répondant
'pas au critères LeCritere
'---------------------------------------------------------------------------------------
'
Private Sub SupprFiltre(LaPlage As Range, ByVal LaColonne As Integer, ByVal LeCritere As String)
With LaPlage
.AutoFilter Field:=LaColonne, Criteria1:="<>" & LeCritere
.Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete
.Parent.AutoFilterMode = False
End With
End Sub
'---------------------------------------------------------------------------------------
'Sub qui permet d'insérer une ligne de titre entre chaque section
'---------------------------------------------------------------------------------------
'
Private Sub SepareSections(Plage As Range)
Dim i As Integer, N As Integer
With Plage
N = .Rows.Count
With .Parent
For i = N To 2 Step -1
If .Range("D" & i) <> .Range("D" & i - 1) Then
.Rows(i).Insert
.Range("A" & i) = "SECTION " & .Range("D" & i + 1)
With .Range("A" & i & ":C" & i)
.HorizontalAlignment = xlCenterAcrossSelection
.Font.Bold = True
End With
End If
Next i
End With
End With
End Sub

Merci d'avance pour toute aide complémentaire ou remarque.

Bonne journée,

FORUM HardWare.fr

Programmation

VB/VBA/VBS

Gestion de tableau avec tri automatique

Sujets relatifs
Copier 37x le même tableau sur une feuille Excel	Interface Graphique et gestion de fichiers
Outil de gestion d'inscriptions à la cantine	pistes pour programmer une gestion de procédure
Produire un tableau html dynamiquement	[VBA excel] incrémentation et impréssion automatique
recréer un tableau après modification d'une valeur	test d'un document ou modification du niveau de gestion d'erreur
[demande] envoi automatique de produit numerique	Problème avec un tableau
Plus de sujets relatifs à : Gestion de tableau avec tri automatique

Page générée en 0.079 secondes