Bonjour, je cherche un script ou un logiciel qui me permettrait lorsque je l’exécuterai dans un dossier de créer des dossiers portant comme nom la date de création des fichiers (2015.08.23 par exemple) contenus dans le dossier et déplaçant chaque fichier inclus dans chaque dossier correspondant à la date de création.
 
Je précise que je ne comprend rien en programmation.
 
Merci

Sous quel OS? Je suppose Windows car apparemment sous Linux il n'y a pas de date de création sauvegardée pour les fichiers...

Voici un truc en Perl bricolé à la va vite, absolument sans garantie, mais qui fonctionne bien chez moi sous XP (oui oui, très vieux   ). Faire valider par un pro et/ou tester intensément avant de l'utiliser en prod!

bug connu: ne gère pas les raccourcis, je suppose qu'il y en a pas...

Pour utiliser installer StrawberryPerl (ou ActiveStatePerl mais j'ai pas testé), sauvegarder le script sous script.pl dans le dossier où il y a les fichiers à traiter puis lancer perl script.pl en ligne de commande (ou créer un raccourci).

Si il y a beaucoup de fichiers on peut virer l'affichage, soit les deux print.

use strict;
use warnings FATAL => 'all';
use autodie;
use File::Copy; #copy() et move()
 
#!SANS GARANTIE!
 
#http://perldoc.perl.org/perlport.html
#stat: [...] ctime is creation time instead of inode change time (Win32).
 
opendir DH, '.';
 
my $file;
 
while(($file=readdir DH))
{
    next if($file eq 'script.pl'); #à ajuster si changement de nom, faut pas que le script essaye de se déplacer lui-même...
    next if(!-f $file); #si c'est un dossier on l'ignore
    
    print "file \"$file\" --> ";
    
    my @t=localtime((stat($file))[10]); #sortir la date de création au format UNIX et convertir 
 
    my $age=sprintf("%04d.%02d.%02d", $t[5]+1900, $t[4]+1, $t[3]); #et mettre dans le bon format
 
    print "$age\n";
    
    if(!-e $age)
    {
        mkdir $age;
    }
    elsif(!-d $age)
    {
        die "erreur: le nom \"$age\" est déjà utilisé par un fichier!";
    }
    
    if(-f $age.'\\'.$file)
    {
        die "erreur: collision: \"$file\" existe déjà dans dossier $age";
    }
    
    copy($file, $age.'\\'.$file); #copy() pour copier ou move() pour déplacer
}
 
closedir DH;

Merci énormément, le programme fonctionne parfaitement.

Par contre, comment faire si je veux que le script traite également les sous répertoires ?

Est-ce que les sous-répertoires peuvent contenir à leur tour des sous-répertoires? Si oui jusqu'à quelle profondeur? Faut-il créer le dossier qui porte la date d'un ou plusieurs fichiers à l'endroit où se trouve le fichier ou plutôt à la racine du truc (là où se trouve le script)? Décris avec précision ce que tu as et ce que tu veux obtenir. Par contre je promets rien, faudra voir si j'ai le temps...

Pour ce genre de truc, il y a un module de base standard en perl, File::Find
 
J'aurais fait un script de ce genre:

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
 
use File::Basename;
use File::Find;
use File::stat;
 
$::PROGRAM = basename $0;
 
sub creation_date {
  my $i = 0;
  my @cdate = map {$_ + (0, 1, 1900)[$i++]} (localtime(stat(shift)->ctime))[3..5];
  return sprintf("%04d.%02d.%02d", reverse @cdate);
}
 
sub process {
  if (-f) {
    my $file = $_;
    # on ne traite pas un fichier de même nom que le script
    return if (/^$::PROGRAM$/);
    # on récupère la date de création au format adéquat
    my $cdate = creation_date($file);
    # on ne fait rien si le fichier est déjà dans le bon répertoire
    return if (basename($File::Find::dir) eq $cdate);
    # Arrêt si le répertoire ne peut être créé à cause d'un fichier de même nom
    die "Erreur: le nom '$cdate' est déjà utilisé par un fichier!" if (-f $cdate);
    # On crée le répertoire s'il n'existe pas
    mkdir $cdate unless (-d $cdate);
    # Arrêt si le fichier existe déjà dans le répertoire
    die "Erreur: collision: '$file' existe déjà dans le dossier $cdate!" if (-f $cdate.'/'.$file);
    # on effectue le déplacement du fichier dans le répertoire
    rename $file, $cdate.'/'.$file;
  }
}
 
find({ bydepth => 1, wanted => \&process, follow => 1 }, '.');

(pas testé au delà d'un cas simple avec quelques fichiers, mais ça me semble OK).
Si on veut un message plus explicite pour les messages de sortie en erreur, on peut faire:
die "Erreur: le nom '$cdate' est déjà utilisé par un fichier dans le répertoire $File::Find::dir!"
et
die "Erreur: collision: '$file' existe déjà dans le dossier $File::Find::dir\\$cdate"
 
A+,
 
P.S. pour le rongeur combatif, je ne sais pas si tu connaissais l'idiome employé dans le map, qui sert a ajuster une liste numérique retournée par une fonction, mais il est assez sympa.

Il y a un module pour à-peu-près tout en Perl, mais faut le savoir (et faut savoir l'utiliser)... Honnêtement pour moi personnellement j'utilise toujours un truc du genre

system('dir * /a-d /b > liste');
open(IN, 'liste', '<');
while(($fichier=<IN> ))
...

Oulà... Ca c'est encore un truc de "Perl pro". Moi je fais du Perl pour débutant... ;-)

C'est quoi cette syntaxe $::XYZ?

Bon, à priori le problème est réglé...

Effectivement, le problème est réglé. Ca m'a donné envie de me mettre à la programmation...
 
Merci beaucoup pour votre temps.

Tout a fait, mais File::Find fait partie des trucs très standard. C'est une transposition de la commande find unix
 

Ça permet d'avoir une variable globale sans faire hurler use strict; :D
Lorsqu'il rencontre  $::XYZ, l'interpréteur sait que c'est une variable dont la portée est le package $main ($:: est une abréviation pour $main::) bref que c'est une variable de package, qui est donc dans un autre namespace que les variables lexicales, pour lesquelles la portée est explicitement indiquée avec l'emploi de my, state, our ou local
 
A+,

Note: Pour que le code soit portable sous Unix & Co, j'ai remplacé les deux '\\' par deux '/' dans le code posté précédemment. Ça m'a sauté aux yeux en relisant.
 
A+,

Moi je ne connais pas (toujours pas) Unix... (mais je finirai par m'y mettre, faudra bien)

Merci pour l'explication!