[Résolu] - [Batch Dos] créer un tache planifiée J+3

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [Résolu] - [Batch Dos] créer un tache planifiée J+3

dob2806

Bonjour à tous,

j'aimerai créer un script que me créé une tache planifiée 3 jours apres avoir executer ce script.

j'essaye de variabliser la commande date /T mais je n'y arrive pas.

voici mon bout de script concernant l'ajout de tache planifiée.

Code :

schdtasks /tn modif-password-ad /tr modif-password-ad.cmd /sc ONCE /sd /st 18:15:00 /ru /rp 1234

si quelqu'un pouvais m'aider.

Merci.

Dob.

Message édité par dob2806 le 09-10-2008 à 16:39:53

Publicité

theshockwave

I work at a firm named Koslow

schdtasks ?

dob2806

il me semble utiliser cette commande

ce que je souhaite c'est lui dire c'est une seule fois dans 3 jours à compter d'aujourd'hui (quand je lance le script).

theshockwave

I work at a firm named Koslow

Tu utilises quel OS ?
Le .cmd de ta ligne de commandes semble indiquer que c'est du Windows, mais sur mon XP Pro, je n'ai pas d'utilitaire schdtasks. Pour planifier des tâches, je passe par la commande "at", mais les arguments n'ont rien à voir (et ce schdtasks a l'air diablement plus pratique que at)

dob2806

windows serveur 2003

MagicBuzz

existe pas sous vista, peut pas tester :spamafote:

theshockwave

I work at a firm named Koslow

peut-être pourrais-tu nous décrire le comportement que tu as (éventuel message d'erreur) et nous donner une copie de ce que te sort un "schdtasks /?"

dob2806

le schdtask fonctionne parfaitement c'est juste que je ne peux que lui dire /sc TODAY+3

MagicBuzz

et tu peux copier un schdtasks /? ici ?

Message édité par MagicBuzz le 30-09-2008 à 14:29:44

dob2806

oups :ange:

http://support.microsoft.com/kb/814596/fr

Publicité

theshockwave

I work at a firm named Koslow

ok, schtasks, là, je l'ai aussi, donc ta ligne plus haut est fausse (vu qu'acessoirement, il te manque aussi le /CREATE, il me semble)

Ce serai possible que tu nous copie exactement ce que tu tentes de faire ?

MagicBuzz

après une tentative foirée de :

Code :

set /a test=%DATE%+3

J'ai dû me rendre à l'évidence, le langage Batch ne sais pas manipuler des dates, ou en tout cas pas aussi simplement.

Par contre j'ai trouvé ça :
http://www.developpez.net/forums/d [...] tes-batch/

En gros, tu reprends son truc pour calculer la bonne date, et ensuite t'as juste à coller la variable calculée en paramètre.

Message édité par MagicBuzz le 30-09-2008 à 15:01:32

dob2806

bon pour faire simple sans se prendre la tete avec la gestion des jours/mois je lancerai le script en cours de moi et avant la fin du moi-3 jours .

J'ai donc ca qui fonctionne mais je n'arrive pas a ajouter +3 a ma variable jouri !!

Code :

for /f "tokens=1,2,3 delims=/" %%i in ('date/T') do (
set jouri=%%i
set moisi=%%j
set anni=%%k
)
Echo %jouri%/%moisi%/%anni%
pause

Message édité par dob2806 le 30-09-2008 à 16:22:59

dob2806

Code :

for /f "tokens=1,2,3 delims=/" %%i in ('date/T') do (
set jour=%%i
set mois=%%j
set anne=%%k
)
set /A jour3=%jour%+3
Echo %jour3%/%mois%/%anne%
pause

voila reste plus qu'a l'inserer dans schtask...

Message édité par dob2806 le 30-09-2008 à 16:31:04

MagicBuzz

ben quoi, c'est bien le 33 septembre

dob2806

PS: aujourd'hui cela ne focntionne forcement pas .... avec un if y a t'il moyen de faire quelque chose de plus simple que ce qu'il y a dans le lien donné aimablement par magibuzz ?

Message édité par dob2806 le 30-09-2008 à 16:32:49

MagicBuzz

malheureusement, oui, y'a toujours plus simple. mais qui marche tout le temps, non.

par contre, tu peux rajouter un simple if %jour% > 25
et à ce moment coller direct le 3 du %mois%+1 (si évidement %mois% < 12) sinon faut aussi faire un %annee%+1

bon, c'est très loin d'être parfait par contre, puisque le test > 25 garanti que ça plantera pas au mois de février, mais des fois ça lancera le script 8 jours plus tard au lieu de 3... (on peut pas tout avoir ^^)

Message édité par MagicBuzz le 30-09-2008 à 16:44:11

theshockwave

I work at a firm named Koslow

juste à titre de rappel, si c'est un besoin critique, tu te prendras sans doute moins la tête en passant par un autre langage de script.

Après, si batch te suffit dans ce cas précis, je n'ai rien à redire.

MagicBuzz

surtout, j'espère que c'est pas le même programme qui doit se replanifier tous les 3 jours, parceque sinon le planificateur de tâche gère ça très bien et sans besoin d'indiquer de date

Message édité par MagicBuzz le 30-09-2008 à 17:02:39

dob2806

c'est un script qui se lance deux à trois fois par ans et c'est une demande et j'essaie tant bien que mal d'y repondre

Message édité par dob2806 le 02-10-2008 à 11:32:29

dob2806

sinon quelqu'un sait pourquoi ce scritp ne fonctionne pas ?

Code :

rem le nombre d jours est passé en paramètre du batch = %1=periode
for /f "tokens=1,2,3 delims=/" %%i in ('date/T') do (
set jouri=%%i
set moisi=%%j
set ani=%%k
)
set periode=%1
if %moisi:~0,1% EQU 0 set moisi=%moisi:~1,1%
if %jouri:~0,1% EQU 0 set jouri=%jouri:~1,1%
set /a diffperiode=(%moisi%*30)+%jouri%
echo debut annee %diffperiode%
set /A difannee=%periode%/365
set /A ani=%ani%-%difannee%
echo %difannee% ; %ani%
set /a difjour=%periode%-(%difannee%*365)
if %diffperiode% LSS %difjour% goto rattrapagemois
set /a moisref=%difjour%/30
echo %moisref%
set /a moisi=%moisi%-%moisref%
echo %moisref% ; %moisi%
set /a jourref=%difjour%-(%moisref%*30)
echo %jourref%
if %jourref% GTR %jouri% (
set /a moisi=%moisi%-1
set jouri=%jourref%-%jouri%
) ELSE (
set /a jouri=%jouri%-%jourref%
)
echo %jourref% ; %jouri%
goto fin
:rattrapagemois
set /A ddif=%difjour%-%diffperiode%
set /A ani=%ani%-1
set /A diffmois=%ddif%/30
echo %diffmois%
echo %ddif%
echo %difjour%
set /a moisi=12-%diffmois%
echo %moisi%
set /A diffjour=%ddif%-(%diffmois%*30)
set /a jouri=%jouri%-%diffjour%
echo %jouri%
:fin
rem on arrive avec %ani% , %moisi% et %jouri%
rem qui sont les jour mois et année compte tenu du cécalage de la période
rem on peut affiner, je suis parti du principe qu'un mois fait 30 jours

dob2806

bon Voila la solution (avec l'aimable participation et resolution de magma² sur www.developpez.com)

Code :

REM ---------------------------------------------------------------------------
REM DEFINITION DE JOUR D'EXECUTION J+3
REM ---------------------------------------------------------------------------
@echo off
set /a NJ=3
set /a J=1%DATE:~0,2% - 100
set /a M=1%DATE:~3,2% - 100
set /a A=%DATE:~6,4%
set /a JJ=%NJ% + ((1461 * (%A% + 4800 + (%M% - 14) / 12)) / 4 + (367 * (%M% - 2 - 12 * ((%M% - 14) / 12))) / 12 - (3 * ((%A% + 4900 + (%M% - 14) / 12) / 100)) / 4 + %J% - 32075)
set /a T0=%JJ% + 68569
set /a T1=(4 * %T0%) / 146097
set /a T0=%T0% - (146097 * %T1% + 3) / 4
set /a T2=(4000 * (%T0% + 1)) / 1461001
set /a T0=%T0% - (1461 * %T2%) / 4 + 31
set /a T3=(80 * %T0%) / 2447
set /a J=%T0% - (2447 * %T3%) / 80
set /a M=%T3% + 2 - (12 * (%T3% / 11))
set /a A=100 * (%T1% - 49) + %T2% + (%T3% / 11)
if %J% LSS 10 set J=0%J%
if %M% LSS 10 set M=0%M%
echo.
echo Dans 3 jours nous serons le %J%/%M%/%A%
echo.
REM ---------------------------------------------------------------------------
REM PLANIFICATION DU SCRIPT DE CHANGEMENT DE MOT DE PASSE DANS 3 JOURS
REM ---------------------------------------------------------------------------
schtasks /delete /tn modif-password-ad /F
schtasks /create /tn modif-password-ad /tr %cd%\modif-password-ad.cmd /sc once /sd %J%/%M%/%A% /st 00:01:00 /ru DOMAIN\administrateur /rp password

Message édité par dob2806 le 09-10-2008 à 16:41:03

Publicité

FORUM HardWare.fr

Programmation

Shell/Batch

[Résolu] - [Batch Dos] créer un tache planifiée J+3

Sujets relatifs
[résolu] [php] Générer une miniature à partir d'une image ?	connexion distante à une bdd [résolu]
[batch] Raccourci "spécial" avec la commande "shortcut"	[Résolu] Manipulation de dates par FILETIME et SYSTEMTIME
[Résolu]-[BATCH DOS] modification Mot De Passe dans l'Active Directory	[Résolu]Petite question trés simple pour comparaison entre deux chaine
[Résolu] Problème avec une boucle	Parcourir un répertoire (Résolu)
Plus de sujets relatifs à : [Résolu] - [Batch Dos] créer un tache planifiée J+3

Page générée en 0.079 secondes