récupérer les parametre d'un table MySQL avec VB

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : récupérer les parametre d'un table MySQL avec VB

mick84m

bonjour,

je développe une applicationn en vb6 avec une base de donné MySQL 4.1.1
j ai besoin de récupérer les infos concernant les tables : nom de la table, nom des champs, le type du champs, NOT NULL (ou pas), la clé primaire....

quels criteres dois-je selectionner dans ma requete??

Publicité

Arjuna

Aircraft Ident.: F-MBSD

Essaie ça (c'est du VBS, ça demande adaptation)

C'est un script que j'avais fait à mon taff pour récupérer les infos de bases divers (Access, SQL Server, MySQL et PostGre). Ca à l'air de marcher quelque soit le DSN utilisé.
Attention cependant : là le script extrait les données des tables pour les mettres dans des fichiers d'import SQL. Faut donc bidouiller un peu pour récupérer ce que tu veux

Code :

Option Explicit
' Changez uniquement cette ligne, afin de mettre le nom du driver ODBC, et le login/pass de la base
Const DSN = "DSN=bidule;UID=root;pwd="
' Déclaration des constantes
Const adSchemaTables = 20
' Déclaration des variables (non typées en VBS)
Dim tablesCpt
Dim linesCpt
Dim cnx
Dim rs
Dim schema
Dim fic
Dim el
Dim str
Dim fso
' Initialisation des compteurs
tablesCpt = 0
linesCpt = 0
' Création de l'objet de connection
Set cnx = CreateObject("ADODB.Connection" )
cnx.Open DSN
' Création de l'objet recordset
Set rs = CreateObject("ADODB.RecordSet" )
Set rs.ActiveConnection = cnx
' Interrogation de la base afin d'obtenir son shema. Correspondra à un "select * from systables" sous SQL Server par exemple
' sauf que cette syntaxe générique fonctionnera avec n'importe quelle base de données.
Set schema = cnx.OpenSchema(adSchemaTables)
' Création de l'objet de gestion des fichiers
Set fso = CreateObject("Scripting.FileSystemObject" )
' Parcours des tables du schema
Do While Not schema.EOF
' On ne prend en compte que les objets "TABLE" : on laisse de côté les vues et les tables système par exemple.
If schema("TABLE_TYPE" ) = "TABLE" Then
tablesCpt = tablesCpt + 1
' On crée le fichier CSV correspondant les données de la table en cours
Set fic = fso.CreateTextFile(schema("TABLE_NAME" ) & ".csv", true)
' On interroge la table et on en récupère la liste des données
rs.Open "select * from " & schema("TABLE_NAME" )
str = ""
' Parcours des headers de la table, et on génère la première ligne du fichier CSV
For Each el in rs.Fields
str = str & Replace(el.Name, ";", "," ) & ";"
Next
fic.WriteLine(left(str, len(str) - 1))
' Parcours de chaque ligne de la table
Do While Not rs.EOF
linesCpt = linesCpt + 1
str = ""
' Récupération des données, et conversion pour les rendre compatibles avec le format CSV
For Each el in rs.Fields
On Error Resume Next
str = str & Replace(Replace(Replace(Replace(CStr("" & el.Value), ";", "," ), vbCr, "\n" ), vbLf, "" ), vbTab, "\t" ) & ";"
If Err <> 0 Then
' Attention : Le type de données n'est pas supporté (BLOB, LONG, TEXT) ou on a trouvé une valeur nulle
If isNull(el.Value) Then
str = str & "NULL;"
Else
str = str & "#UNSUPPORTED DATA TYPE#;"
End If
Err.Clear
End If
On Error Goto 0
Next
' Ecriture de la ligne dans le fichier CSV
if len(str) > 1 then
fic.WriteLine(left(str, len(str) - 1))
else
fic.WriteLine("" )
end if
' Passage à la ligne suivante
rs.MoveNext
Loop
rs.Close
fic.Close
Set fic = Nothing
End If
' Passage à la table suivante
schema.MoveNext
Loop
' Fermeture et destruction des objets de la base de données et de gestion des fichiers.
schema.Close
cnx.Close
Set fso = Nothing
Set rs = Nothing
Set schema = Nothing
Set cnx = Nothing
MsgBox(CStr(linesCpt) & " lignes réparties dans " & CStr(tablesCpt) & " ont été correctement exportées." )

mick84m

merci je vais essayer, je te tiens au courant

mick84m

merci pour ton aide, mais récupérer les occurences de la tables je le fais déjà...
ce qu il me faut c'est les paramètres des tables genre nombre et nom des champs, le type de donnée (text, int, bool,...), valeur par défaut, ...

Arjuna

Aircraft Ident.: F-MBSD

Mise à part les valeurs par défaut, mon script récupère déjà le type et le nom des champs (par contre, les types sont sous forme numérique, et correspondent à des constantes ADO, c'est à dire que ce sont les types "génériques" qui sont donnés)

mick84m

ok j ai trouvé mon bonheur avec

show create table <matable>
il me donne l export de la crétaion de base.
mais ca ne donne pas les INSERT INTO...
connais tu une commande mysql me permettant de les obtenir, car j utilise une procedure qui est vraiment galere a gerer...

si qql un peu tm aider... merci

Arjuna

Aircraft Ident.: F-MBSD

Mon truc le fait

Arjuna

Aircraft Ident.: F-MBSD

(sauf qu'il fait pas des insert into, mais des fichiers CSV, ça demande 30 secondes à modifier)

mick84m

y a un probleme avec les fichier CSV c est qu ils sont carrément plus volumineux que des fichiers text...de plus ma table contient plus de 300 000 enregistrements, et c est vraiment pas pratique a manipuler...si tu vois ce que j veux dire.
cette table n est qu une table de test, la vrai contient des millions d enregistrements...

Arjuna

Aircraft Ident.: F-MBSD

Rien compris.

Déjà un fichier CSV, c'est au contraire le format d'extraction le plus petit possible (à côté d'un fichier à pas fixe, le nombre de caractères supplémentaires est minime).
Ensuite, tu demandes à générer des requêtes "INSERT" à la place du CSV, ce qui est au TRES GRAND MINIMUM deux fois plus volumineux qu'un CSV.

Comprend rien à ton truc.

Le CSV, c'est pas du XML hein

Publicité

mick84m

c est pas grave merci de ton aide, j ai trouvé une autre solution pour contourné ce problème.

merci, bon courage pour la suite

FORUM HardWare.fr

Programmation

SQL/NoSQL

récupérer les parametre d'un table MySQL avec VB

Sujets relatifs
récupérer les parametre d'un table MySQL avec VB	[resolu][MYSQL] CREATE VIEW ???
Test sur un mysql_fetch_array	Insertion de données mySQL vers Excel
[Mysql] Erreur avec des fichiers .ibd	[MySQL] Licence commercial ou pas ?
Plus de sujets relatifs à : récupérer les parametre d'un table MySQL avec VB

Page générée en 0.061 secondes