Ada

[Ada/Asm] Accéder au port parallèle avec Ada sur Gnu/Linux (résolu)

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [Ada/Asm] Accéder au port parallèle avec Ada sur Gnu/Linux (résolu)

Profil supprimé

Bonjour, je me doute bien que c'est possible, mais j'ai pas encore trouvé comment.
J'ai devant moi "Ingénierie du logiciel avec Ada" Traduction de Grady Booch.
Chapitre 17 on aborde le traitement d'exceptions et les fonctionnalités de bas niveau.
Même si je me plante dans l'architecture de ma machine, je lis page 391...
Et je copie à ma sauce.

Code :

--------------------------------------------------------------------------------------------------------------------------------------------
--                                                                                                                                        --
--------------------------------------------------------------------------------------------------------------------------------------------
-- Unit Name   : "Main"                                                                                                                   --
-- Filename    : "main.adb"                                                                                                               --
-- Author      : "jovalise"                                                                                                               --
-- Date        : "Sat Nov 12 01:00:00 CET 2011"                                                                                           --
-- Version     : "0"."0"."0"-"alpha"                                                                                                      --
-- Description : ""                                                                                                                       --
--                                                                                                                                        --
--------------------------------------------------------------------------------------------------------------------------------------------
with System;
use System;
procedure Main is
 
 
   type Io_Port is
      record
         Data               : Integer range 0..255;
         Busy               : Boolean;
         Interrupt_Validity : Boolean;
      end record;
 
   Mot : constant := 1*8;
 
   for Io_Port use
      record at mod 2;
      Data              at 0*Mot range 0..7;
      Busy              at 1*Mot range 3..3;
      Interrupt_Validity at 1*Mot range 7..7;
      end record;
 
   LPT1_Data : Io_Port;
   LPT1_Ctrl : Io_Port;
   for LPT1_Data use at 16#378#;
   for LPT1_Ctrl use at 16#37A#;
 
Begin
 
 
   null;
end Main;

Mais jamais, les ligne 35 et 36 ne passe au compilateur qui me dit :

void:Ada# gnatmake Sources/main -o Targets/main -gnat83
gcc-4.3 -c -ISources/ -gnat83 -I- Sources/main.adb
main.adb:35:25: expected private type "System.Address"
main.adb:35:25: found type universal integer
main.adb:36:25: expected private type "System.Address"
main.adb:36:25: found type universal integer
gnatmake: "Sources/main.adb" compilation error
void:Ada#

Mon issue est peut-être dans l'astuce pour passer un type address la ou j'ai mis un universal integer.
Sauriez vous comment s'y prendre ?
Merci pour votre aide.

Message édité par Profil supprimé le 15-11-2011 à 01:19:57

Publicité

Profil supprimé

Bonjour je viens de trouver comment assigner mon adresse que je connais sous forme numérique ; En utilisant la fonction To_Address comme suit :

Code :

for LPT1_Data use at System'To_Address(16#378#);
for LPT1_Ctrl use at System'To_Address(16#37A#);

Profil supprimé

Pour le moment je me tape que des Storage_Error.

Je tente également l'asm, avec ce code..

Code :

--
      Asm("mov %%al, 0" & LF & HT &
          "mov %%dx,0x378" & LF & HT &
          "out %%al, %%dx" & LF & HT);

Je voudrais écrire 0(zero) sur le port parallèle situé à l'adresse 0x378.
Mais je me tape encore un storage_error.

Mais la, faut que j'invoque Harko peut-être !

Message édité par Profil supprimé le 14-11-2011 à 14:25:34

Profil supprimé

J'en suis là,

Code :

with Interfaces;
use Interfaces;
with System.Machine_Code;
use System.Machine_Code;
with Ada.Text_Io;
procedure Main is
 
   use Ascii;
 
   LPT1     : Unsigned_16 := 16#0378#;
   In_Value : Unsigned_8 := 255;
   Out_Value : Unsigned_8 := 0;
begin
 
   Asm("mov %2, %%al" & LF & HT &
         "mov %1, %%dx" & LF & HT &
         "out %%al, %%dx"  & LF & HT &
         "mov %0, %%al",
       Inputs  => (Unsigned_16'Asm_Input ("g", LPT1), Unsigned_8'Asm_Input ("b", In_Value)),
       Outputs => Unsigned_8'Asm_Output ("=b", Out_Value));
   delay 0.25;
   Ada.Text_Io.Put_Line("Value = " & Unsigned_8'Image(Out_Value));
end Main;

J'avais trouvé un code qui compilait et s'exécutait sans erreur mais sans avoir le résultat escompté, et je l'ai perdu.
Celui-ci lève une l'erreur Storage_Error, stack overflow (or erroneous memory access) au moment d'exécuter "out".

Profil supprimé

Avec les permissions d'accès au port ça marche !. [:nozdormu]

Profil supprimé

Petit set de 4 fichiers qui vont bien...

Code :

-- Provide parallel ports address on Compatible IBM PC
package Pp is
 
   LP0 : constant := 16#0278#;
   LP1 : constant := 16#0378#;
   LP2 : constant := 16#03BC#;
   type Message_Type is (Data, Status, Ctrl);
end Pp;

Code :

-- Provide Gnu/Linux basic function to obtain desired IO permissions.
with Interfaces.C;
use Interfaces;
package Pp.Ioperm is
 
   function Ioperm(From : in C.Unsigned_Long;
                   Num : in C.Unsigned_Long;
                   Tuen_On : in C.Int) return C.Int;
   pragma Import(C, Ioperm, "ioperm" );
 
end Pp.Ioperm;

Code :

-- Provide tow basic function to read and write value to parallel port.
with Interfaces;
generic
   LP : Interfaces.Unsigned_16;
package Pp.Pp_Io is
   use Interfaces;
   procedure Put(Msg : in Message_Type; Value : in Unsigned_8);
   procedure Get(Msg : in Message_Type; Value : out Unsigned_8);
end Pp.Pp_Io;

Code :

with System.Machine_Code;
use System.Machine_Code;
package body Pp.Pp_Io is
 
   use Interfaces, Ascii;
 
   procedure Put(Msg : in Message_Type; Value : in Unsigned_8) is
 
   begin
      Asm("mov %1,   %%al" & LF & HT &
            "mov %0,   %%dx" & LF & HT &
            "out %%al, %%dx",
          Inputs  => (Unsigned_16'Asm_Input ("g", LP+Message_Type'Pos(Msg)), Unsigned_8'Asm_Input ("a", Value)),
          Volatile => True);
   end Put;
 
   procedure Get(Msg : in Message_Type; Value : out Unsigned_8) is
 
   begin
      Asm("mov %1,%%dx" & LF & HT &
            "in %%dx,%%al" & LF & HT &
            "mov %0, %%al",
          Inputs  => (Unsigned_16'Asm_Input ("g", LP+Message_Type'Pos(Msg))),
          Outputs => Unsigned_8'Asm_Output ("=a", Value),
          Volatile => True);
   end Get;
end Pp.Pp_Io;

Et un programme de test :

Code :

with Interfaces.C;
use interfaces;
with Text_Io, Ada.Integer_Text_Io;
use Ada;
 
with Pp.Ioperm, Pp.Pp_Io;
use Pp;
procedure Pp_Test is
 
   package Lpt1 is new Pp.Pp_Io(Pp.LP1);
 
   Value : Unsigned_8 := 0;
   Errno : C.Int := Pp.Ioperm.Ioperm(PP.LP1, 3, 1);
begin
   if C."/="(Errno, 0) then
      raise Program_Error;
   end if;
   Lpt1.Put(Data, 128);
   delay 3.0;
   Lpt1.get(Data, Value);
   Text_Io.Put("Value = " );
   Integer_Text_Io.Put(integer(Value), Base => 16);
   Text_Io.New_Line;
   delay 3.0;
   Lpt1.Put(Data, 0);
   Lpt1.get(Data, Value);
   Text_Io.Put("Value = " );
   Integer_Text_Io.Put(integer(Value), Base => 16);
   Text_Io.New_Line;
   Errno := Pp.Ioperm.Ioperm(PP.LP1, 3, 0);
end Pp_Test;

Edit, j'espère avoir apporté toute les correction qui s'imposaient.

Message édité par Profil supprimé le 14-11-2011 à 21:16:27

Profil supprimé

Arff, j'ai pas fait gaffe à ce que j'avais fait en fait, et ... Pp-Pp_Io.Get ne fonctionne pas.
J'y retourne.

Je sais, mais bon, c'est la vie.

Profil supprimé

Voila, c'est corrigé, dans les deux cas ici, pour put et get il faut spécifier True pour le paramètre Volatile de Asm.
Dans "get", on peut même biaiser %%al et utiliser in en écrivant directement dans la variable de sortie.

Message édité par Profil supprimé le 14-11-2011 à 21:08:52

FORUM HardWare.fr

Programmation

Ada

[Ada/Asm] Accéder au port parallèle avec Ada sur Gnu/Linux (résolu)

Sujets relatifs
[Résolu] Problème pour acceder à un site bancaire	[Résolu] Net::Ping sur un port forwarding en localhost
[Algo] Abstraction de graphe et algo.	[Ada] Skeye et le basket du lundi
[RESOLU] Règle de calcul des frais de port pour panier	Accéder à une BDD depuis un autre PC
[Ada][SGBD][Gnade][Mysql]Galère avec Gnade.MySQL	[Ada][Warborg] un wargame avec GtkAda
[Ada Project] Anothers Implementation Of Artificial Intelligence	[Ada][Programmation Orienté Objet] déclaration de procédure abstraite.
Plus de sujets relatifs à : [Ada/Asm] Accéder au port parallèle avec Ada sur Gnu/Linux (résolu)

Page générée en 0.078 secondes